#l;

#-- replace all tabs with two spaces
s@	@  @g;
#-- html entities.
s@&@\&@g;
s@<@\&lt;@g;
s@>@\&gt;@g;

#-- stop formatting between '-->' and '--<'
/^ *--&gt;/,/^ *--&lt;/ {
 s/--&gt;/<pre>/;
 s/--&lt;/<\/pre>/;
 b; 
}

#-- stop formatting on line that has ":>"
/^ *:&gt;/ {
 s@:&gt;@<br/>\&nbsp;\&nbsp;\&nbsp;<code>@;
 s@$@</code></center><br/>@;
 b;
}

#-- mark up language generative grammar rules
/^ *rule: / {
 s@rule:\(.*\)$@<em><strong>\1</strong></em><br/>@;
}

#-- if the file contains DOS newlines line below may be necessary
#-- in order to get rid of the "\r" characters.
#s@.$@@g
#
s@\([ ][ ]*\)@ @g

#--------------------------
#-- lists
#-- definition lists, the term begins with a "-" and 
#-- ends which a ":" at the end of a line or followed by a 
#-- space. The list end with a blank line eg;
#--  D- sea: a lot of water
#--   - see: look with the eyes
#--
        
/^[ ]*D-/,/^[ ]*$/ {
  s@^\([ ]*\)D-\(.*\):$@\1<dl><dt><em> \2 </em><dd>@;
  s@^\([ ]*\)D-\(.*\): @\1<dl><dt><em> \2 </em><dd>@;
  s@^\([ ]*\)-\(.*\): @\1<dt><em> \2 </em><dd>@;
  s@^\([ ]*\)-\(.*\):$@\1<dt><em> \2 </em><dd>@;
  s@^\([ ]*\)$@\1</dl>\
  @;
}

#-- attempt to mark up sections of text which refer to the 
#-- state of a virtual machine
/^[ ]*-machine-/,/^[ ]*$/ {
  s@^\([ ]*\)-machine-$@\1<table border=1>@;
  /^ *-/ { 
    s@-workbuffer:@-workspace:@;
    s@^\([ ]*\)-workspace:\(.*\)$@\1<tr><td align="right"><strong>workspace</strong></td><td colspan=5>\2</td></tr>@g;
    s@,@</td><td>@g; 
    s@^\([ ]*\)-\([^:]*\):\(.*\)$@\1<tr><td align="right"><strong>\2</strong></td><td>\3</td></tr>@g;
  }
  s@^\([ ]*\)$@\1</table><p>\
  @;
}
#-- title
s@^[ ]*==\(.*\)@<h2>\1</h2>@

#-- headings
#s@^[ ]*\*\*\(.*\)@<h3><img src="/chess/white-queen.png" />\1</h3>@
s@^[ ]*\*\*\(.*\)@<h3>\&clubs;\1</h3><hr/>@

#-- files
s@ \(/[^ /][^ /]*/[^ ]*\)@ <tt>\1</tt>@g

#-- special links
#-- format: "location" (googlemap)
s@"[ ]*(maplink)@" (googlemap)@Ig;
s@"[ ]*(map)@" (googlemap)@Ig;
s@"\([^"][^"]*\)"[ ]*(googlemap)@<a href="http://maps.google.com/maps?hl=au\&q=\1" title="display google map" class="googlemap">\1</a>@g
#-- format: "term" (google)
s@"\([^"][^"]*\)"[ ]*(google)@<a href="http://www.google.com/search?q=\1" title="search google">\1</a>@g
#-- format: "term" (wikipedia)
s@"[ ]*(wikipedia)@" (wikisearch)@Ig;
s@"[ ]*(wpsearch)@" (wikisearch)@Ig;
s@"\([^"][^"]*\)"[ ]*(wikisearch)@<em>\1</em>\
<a href="http://en.wikipedia.org/wiki/Special:Search?search=\1" title="wikipedia entry for '\1'" class="wikipedia">\
<small>\&rarr;W</small></a>@g

#-- format: "term" (wikipedia:nn) where "nn" is any language code
s@"\([^"][^"]*\)"[ ]*(wikipedia:\([a-z][a-z]\))@<a href="http://\2.wikipedia.org/wiki/Special:Search?search=\1">\1</a>@g
#-- format: "term" (google:nn) 
s@"\([^"][^"]*\)"[ ]*(google:\([a-z][a-z]\))@<a href="http://www.google.com/search?hl=\2\&q=\1">\1</a>@g
 
#-- links
#-- format: the "something" command 
s@the *"\([^"][^"]*\)" command@the <tt>"\1"</tt> command@Ig
#-- format: file "filename"
s@file *"\([^"][^"]*\)"@file <a href="\1" title="view file">\1</a>@Ig
#-- format: the "something" directory
s@the  *"\([^"][^"]*\)"  *directory@the <a href="\1" title="view directory">\1</a> directory@g
s@"\([^"][^"]*\)" [ ]*link://\([^ ][^ ]*\)@<a href="\2" title="view file">\1</a>@g
s@"\([^"][^"]*\)" [ ]*file://\([^ ][^ ]*\)@<a href="\2" title="view file">\1</a>@g
s@"\([^"][^"]*\)" [ ]*vir://\([^ ][^ ]*\)@<a href="\2.html" title="view file">\1</a>@g
s@"\([^"][^"]*\)" [ ]*\(http://[^ ][^ ]*\)@<a href="\2" title="view page">\1</a>@g
s@"\([^"][^"]*\)" [ ]*\(ftp://[^ ][^ ]*\)@<a href="\2" title="view page">\1</a>@g
s@"\([^"][^"]*\)" [ ]*\(www\.[^ ][^ ]*\)@<a href="http://\2" title="view page">\1</a>@g

#-- "vir" works in conjunction with apache mod rewrite rules
#-- to display text files as html
s@ vir://\([^ ][^ ]*\)@ <a href="\1.html" title="view file">\1</a>@g
s@^vir://\([^ ][^ ]*\)@ <a href="\1.html" title="view file">\1</a>@g
s@ file://\([^ ][^ ]*\)@ <a href="\1" title="view file">\1</a>@g
s@^file://\([^ ][^ ]*\)@ <a href="\1" title="view file">\1</a>@g
s@ link://\([^ ][^ ]*\)@ <a href="\1" title="view file">\1</a>@g
s@^link://\([^ ][^ ]*\)@ <a href="\1" title="view file">\1</a>@g
s@ \(http://[^ ][^ ]*\)@ <a href="\1" title="view page">\1</a>@g
s@^\(http://[^ ][^ ]*\)@<a href="\1" title="view page">\1</a>@g
s@ \(ftp://[^ ][^ ]*\)@ <a href="\1">\1</a>@g
s@^\(ftp://[^ ][^ ]*\)@<a href="\1">\1</a>@g
s@ \(gopher://[^ ][^ ]*\)@ <a href="\1">\1</a>@g
s@^\(gopher://[^ ][^ ]*\)@<a href="\1">\1</a>@g
s@ \(www\.[^ ][^ ]*\)@ <a href="http://\1" title="view page">\1</a>@g
s@^\(www\.[^ ][^ ]*\)@<a href="http://\1" title="view page">\1</a>@g

s@--&gt;@\&rarr;@g
s@&lt;--@\&larr;@g


#-- unordered lists
/^[ ]*u-/,/^[ ]*$/ {
  s@^\([ ]*\)u-@\1<ul><li>@;
  s@^\([ ]*\)-@\1<li>@;
  s@^\([ ]*\)$@\1</ul>\
  @;
}

#-- ordered lists
/^[ ]*o-/,/^[ ]*$/ {
  s@^\([ ]*\)o-@\1<ol><li>@;
  s@^\([ ]*\)-@\1<li>@;
  s@^\([ ]*\)$@\1</ol>\
  @;
}


#-- attempts to mark up "faq" (frequently asked questions) sections of documents
#-- example of format
#-- (-faq-)
#--   * what is an faq?
#--     an faq is a set of questions and answers
#-- (-/faq-)
/^[ ]*(-faq-)/,/^[ ]*(-\/faq-)/ {
  s@^\([ ]*\)(-faq-)@\1<dl class="faq">@;
  s@^\([ ]*\)\*@\1<dt><em>@;
  s@?@?</em><dd>@;
  s@^\([ ]*\)(-/faq-)@\1</dl>@;
}

#-- journal
/^[ ]*(-jour-)/,/^[ ]*(-\/jour-)/ {
  s@^\([ ]*\)(-jour-)@\1<dl class="journal">@;
  s@^\([ ]*\)\([0-9][0-9].*\)@\1<dt>\2<dd>@;
  s@^\([ ]*\)(-/jour-)@\1</dl>@;
}

s@^\([ ]*\)$@<p>@;
s@:$@:<br/>@;